mirror of
https://github.com/gabime/spdlog.git
synced 2026-04-10 11:34:29 +08:00
12d65eebe6
* docs(tasks): v1.x inventory, triage template, merge report; update task checklist - Record merge-base and export v1-only commits (v2..v1) - Document failed merge attempt: v2 file tree diverges from v1 - Mark completed checklist items 0.x, 1.x, merge report draft (5.2) Made-with: Cursor * fix(pattern): %z with UTC pattern time shows +00:00 (port v109a674b7) - z_formatter takes pattern_time_type; emit +00:00 when pattern uses UTC - Track port in tasks/commits-ported.txt and merge-report; update checklist Made-with: Cursor * fix(os): Windows utc_minutes_offset via mktime/_mkgmtime (port v1b656d1ce) - Replace GetTimeZoneInformation-based offset with v1.x mktime/_mkgmtime approach - Add tests/test_timezone.cpp and extend pattern_formatter tests; update os.h comment Made-with: Cursor * test(timezone): POSIX TZ with DST rules; include fcntl in tcp_client_unix (v1 ports) -0f7562a0: EST5EDT / IST-2IDT macros for POSIX vs Windows -d2100d5d: fcntl.h for Unix tcp client header (v2 path) Made-with: Cursor * feat(tcp): connect timeouts and socket IO timeouts; ci: checkout@v6 (v1 ports) -9ecdf5c8: connect_socket_with_timeout on Unix/Windows; tcp_sink timeout_ms -3c61b051: actions/checkout@v6 on all workflows - tcp_sink: remove duplicate #pragma once Made-with: Cursor * feat(dup_filter_sink): ctor with sink list (v145b67eee); add full v1 SHA triage table - tasks/v1-triage-complete.md: 245 commits PORTED/PENDING/N/A for PRD 3A tracking - Merge report and task checklist updated Made-with: Cursor * feat(level): case-insensitive level_from_str; cmake: BUILD_TYPE only if top-level (v1 ports) -566b2d14: common.cpp + test_misc (SUPERSEDED note ford5af52d9in triage) -dd3ca04a: guard default CMAKE_BUILD_TYPE for add_subdirectory consumers - Update v1-triage-complete.md counts and statuses Made-with: Cursor * v1 parity: MSVC UTF-8, ansicolor/syslog/os, getenv, triage docs - CMake: SPDLOG_MSVC_UTF8 + /utf-8 for real MSVC only - ansicolor: protected target_file_; fix set_color_mode_ lock nesting - os: drop redundant fileapi.h; spdlog::details::os::getenv via std::getenv - tests: stopwatch waits 500ms; includes/triage/commits-ported/merge-report updates - Reclassify superseded v1 SHAs (Sep, syslog, stopwatch ms, utf8 tests, etc.) Made-with: Cursor * parity: ringbuffer zero capacity, utf8 assert; v1 triage sync - ringbuffer_sink: throw if n_items==0 (#3436); test expects spdlog_ex - utf8_to_wstrbuf: assert compares int to static_cast<int>(target.size()) (#3479) - Triage: PORTEDad725d34getenv,677a2d93stopwatch,3f7e5028, a6215527; SUPERSEDEDa45c9390,eeb22c13,5673e9e5,fe4f9952,287333ee- tasks: 27 PORTED / 26 SUPERSEDED / 78 PENDING; merge-report + commits-ported Made-with: Cursor * docs(tasks): note regular commits and push after parity ports Made-with: Cursor * parity: dup_filter_sink notification level from last duplicate (#3390) - Remove notification_level ctor arg; track skipped_msg_log_level_ on duplicate skips - Test: skipped summary line uses same short level as duplicated messages - Triage:847db337PORTED; 28/26/77 counts; merge-report + commits-ported Made-with: Cursor * parity: UWP getenv (WINAPI_FAMILY); triage fmt/cfg/no-except - os_windows: detect non-desktop/UWP for empty getenv (#3489) - Triage: PORTED 8806ca65; SUPERSEDEDe3f5a4fee655dbb6; N/Aae1de0dc548b2642- Counts 29/28/116/72; merge-report + commits-ported Made-with: Cursor * parity: qt_sinks sign casts (#3487); triage9c582574superseded - qt_color_sink: qsizetype for UTF-8 color range lengths; index colors_ with size_t - SUPERSEDED:9c582574— os_unix utc_minutes_offset already matches #3366 - Counts 30/29/70; merge-report + commits-ported Made-with: Cursor * parity: SPDLOG_NO_TZ_OFFSET (#3483); triage #3360 superseded - CMake: option SPDLOG_NO_TZ_OFFSET; PUBLIC compile definition when ON - z_formatter: +??:?? when macro; else keep UTC +00:00 and local offset - utc_minutes_offset: stub on Unix/Windows when macro - test_pattern_formatter: %z UTC case matches placeholder when NO_TZ - SUPERSEDED10320184(ScopedPadder / %D already in v2) - Triage 31/30/68; merge-report + commits-ported Made-with: Cursor * triage: supersede5931a3d6ba50805747b7e7c7(already on v2 tree) Made-with: Cursor * tasks: sync 5.1 triage counts (33 superseded, 65 pending) Made-with: Cursor * parity: MSVC/clang hygiene #3515–#3519 #3521; triage batch - dup_filter_sink: filter_ const, const filter_duration (#3515) - logger: should_flush uses flush_level() (#3516) - daily_file_sink: new_filename locals (#3516) - spdlog::should_log(level log_level) (#3519) - example my_type value_ / ctor param (#3521) - Triage: PORTED1774e700309204d5f2a9dec0472945ba; N/Ad299603e57505989; SUPERSEDED1ef8d3ce8cfd4a7e; fixba508057row Made-with: Cursor * parity: udp_sink const udp_sink_config& (#3520); triagefc7e9c871685e694- dist_sink already used std::move(sinks) - SUPERSEDED: no common-inl.h on v2; log_with_format_ avoids fmt copy path (#3541) Made-with: Cursor * parity: README fmt::format_to (#3259); triage2670f47dd276069a951c5b99- Document ambiguous format_to fix in README user-defined type example - SUPERSEDED: z_formatter warning, fmt11 const formatter, rotate_now + test Made-with: Cursor * parity: lock rotate_now mutex (#3281); triagea2b42620f355b3d5d276069a- rotating_file_sink::rotate_now matches #3281 (sync with sink_it_) - SUPERSEDED: CMake 3.10..3.21 (v2 uses 3.23); daily test fmt::format; fmt11 const row Made-with: Cursor * parity: basic_file_sink::truncate (#3280); triage fwrite/fmt/test batch - truncate(): lock + file_helper::reopen(true) - test basic_file_sink_truncate - SUPERSEDED:b7e0e2c271925ca3fa6605dc885b547396c9a62b1e6250e1d7155530Made-with: Cursor * parity: test_sink/callback iterator cast (#3315); triage Catch2 #3038 - difference_type cast for formatted.end() - eol_len (ad0f31c0) - SUPERSEDED:c1569a3dCatch2 v3.5.0,73e2e02bwstr_to_utf8buf bounds Made-with: Cursor * parity: SPDLOG_WCHAR_CONSOLE WriteConsoleW path (#3092); triageb6da5944- WIN32 option SPDLOG_WCHAR_CONSOLE; SPDLOG_UTF8_TO_WCHAR_CONSOLE in private defs - wincolor print_range_: utf8_to_wstrbuf + WriteConsoleW when defined - N/A: async_msg flush_callback move-assign (no v1 shape on v2) Made-with: Cursor * triage: v1 async_logger/thread_pool + fmt 11.1 batch (15 SHAs) - N/A:fe79bfcc6725584easync tests16e0d2e763d18842d8e0ad461e7d7e073c23c27d- SUPERSEDED:faa0a7a985bdab0c276ee5f57f8060d596a8f625- Counts: 58 SUPERSEDED, 129 N/A, 17 PENDING; merge-report subsection Made-with: Cursor * Port v1 TSAN CMake (#3237); close 3A triage (MDC N/A, fmt 5A) Made-with: Cursor * docs(triage): note 3A table complete Made-with: Cursor * 5A: bundle fmt 12.1.0 (match v1.x), FMT_INSTALL, MSVC /wd4834, find_dependency(fmt 12) Made-with: Cursor * docs(5.4): migration and release notes for v1 parity integration branch Made-with: Cursor * docs: cross-link migration notes; refresh PRD/tasks/merge-report for completed 5A/3A Made-with: Cursor * revert: remove README and PRD cross-links to migration notes Made-with: Cursor * docs(merge-report): audit — add9fe79692to ports table; fix6004e3d1paths Made-with: Cursor * Remove tasks * PR comment fixes * Fix small random issues * Fix PR comments - un-remove the comment and allow any fmt library version --------- Co-authored-by: Jan Moravec <jan.moravec@hidglobal.com>
346 lines
16 KiB
CMake
346 lines
16 KiB
CMake
# ---------------------------------------------------------------------------------------
|
|
# Copyright(c) 2019-present by spdlog authors.
|
|
# Distributed under the MIT License (http://opensource.org/licenses/MIT)
|
|
# ---------------------------------------------------------------------------------------
|
|
cmake_minimum_required(VERSION 3.23)
|
|
include(cmake/utils.cmake)
|
|
include(cmake/ide.cmake)
|
|
spdlog_extract_version()
|
|
project(spdlog VERSION ${SPDLOG_VERSION} LANGUAGES CXX)
|
|
include(GNUInstallDirs)
|
|
set_property(GLOBAL PROPERTY USE_FOLDERS ON)
|
|
# ---------------------------------------------------------------------------------------
|
|
# Set default build to release
|
|
# ---------------------------------------------------------------------------------------
|
|
if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
|
|
# Set CMAKE_BUILD_TYPE only if this project is top-level (avoid overriding parent)
|
|
if ((DEFINED PROJECT_IS_TOP_LEVEL AND PROJECT_IS_TOP_LEVEL) OR
|
|
(NOT DEFINED PROJECT_IS_TOP_LEVEL AND CMAKE_SOURCE_DIR STREQUAL PROJECT_SOURCE_DIR))
|
|
set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose Release or Debug" FORCE)
|
|
endif ()
|
|
endif ()
|
|
# ---------------------------------------------------------------------------------------
|
|
# Compiler config
|
|
# ---------------------------------------------------------------------------------------
|
|
# C++ standard >=17 is required
|
|
if (NOT DEFINED CMAKE_CXX_STANDARD)
|
|
set(CMAKE_CXX_STANDARD 17)
|
|
elseif (CMAKE_CXX_STANDARD LESS 17)
|
|
message(FATAL_ERROR "Minimum supported CMAKE_CXX_STANDARD is 17, but it is set to ${CMAKE_CXX_STANDARD}")
|
|
endif ()
|
|
set(CMAKE_CXX_STANDARD_REQUIRED ON)
|
|
set(CMAKE_CXX_EXTENSIONS OFF)
|
|
if (CMAKE_SYSTEM_NAME MATCHES "CYGWIN" OR CMAKE_SYSTEM_NAME MATCHES "MSYS" OR CMAKE_SYSTEM_NAME MATCHES "MINGW")
|
|
set(CMAKE_CXX_EXTENSIONS ON)
|
|
endif ()
|
|
# ---------------------------------------------------------------------------------------
|
|
# Set SPDLOG_MASTER_PROJECT to ON if we are building spdlog
|
|
# ---------------------------------------------------------------------------------------
|
|
# Check if spdlog is being used directly or via add_subdirectory, but allow overriding
|
|
if (NOT DEFINED SPDLOG_MASTER_PROJECT)
|
|
if (CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_SOURCE_DIR)
|
|
set(SPDLOG_MASTER_PROJECT ON)
|
|
else ()
|
|
set(SPDLOG_MASTER_PROJECT OFF)
|
|
endif ()
|
|
endif ()
|
|
# ---------------------------------------------------------------------------------------
|
|
# Options
|
|
# ---------------------------------------------------------------------------------------
|
|
option(SPDLOG_BUILD_ALL "Build all artifacts" OFF)
|
|
option(SPDLOG_BUILD_SHARED "Build shared library" OFF)
|
|
option(SPDLOG_BUILD_EXAMPLE "Build example" ${SPDLOG_MASTER_PROJECT})
|
|
option(SPDLOG_BUILD_TESTS "Build tests" OFF)
|
|
option(SPDLOG_BUILD_BENCH "Build benchmarks (Requires https://github.com/google/benchmark.git to be installed)" OFF)
|
|
option(SPDLOG_SANITIZE_ADDRESS "Enable address sanitizer for the spdlog library and anything that links it" OFF)
|
|
option(SPDLOG_SANITIZE_THREAD "Enable thread sanitizer for the spdlog library and anything that links it" OFF)
|
|
if (SPDLOG_SANITIZE_ADDRESS AND SPDLOG_SANITIZE_THREAD)
|
|
message(FATAL_ERROR "SPDLOG_SANITIZE_ADDRESS and SPDLOG_SANITIZE_THREAD are mutually exclusive")
|
|
endif ()
|
|
option(SPDLOG_BUILD_WARNINGS "Enable compiler warnings" OFF)
|
|
option(SPDLOG_SYSTEM_INCLUDES "Include as system headers (skip for clang-tidy)." OFF)
|
|
option(SPDLOG_INSTALL "Generate the install target" ${SPDLOG_MASTER_PROJECT})
|
|
option(SPDLOG_FMT_EXTERNAL "Use external fmt library instead of of fetching from gitub." OFF)
|
|
if (${CMAKE_SYSTEM_NAME} STREQUAL "Linux")
|
|
option(SPDLOG_CLOCK_COARSE "Use CLOCK_REALTIME_COARSE instead of the regular clock," OFF)
|
|
else ()
|
|
set(SPDLOG_CLOCK_COARSE OFF CACHE BOOL "non supported option" FORCE)
|
|
endif ()
|
|
option(SPDLOG_PREVENT_CHILD_FD "Prevent from child processes to inherit log file descriptors" OFF)
|
|
option(SPDLOG_NO_THREAD_ID "prevent spdlog from querying the thread id on each log call if thread id is not needed" OFF)
|
|
option(SPDLOG_DISABLE_GLOBAL_LOGGER "Disable global logger creation" OFF)
|
|
option(SPDLOG_NO_TLS "Disable thread local storage" OFF)
|
|
option(SPDLOG_NO_TZ_OFFSET "Omit %z timezone offset (use on platforms without tm_gmtoff / full offset)" OFF)
|
|
option(SPDLOG_TIDY "run clang-tidy" OFF)
|
|
set(SPDLOG_DEBUG_POSTFIX "-${SPDLOG_VERSION_MAJOR}.${SPDLOG_VERSION_MINOR}d" CACHE STRING
|
|
"Filename postfix for libraries in debug builds (empty string allowed)")
|
|
option(SPDLOG_MSVC_UTF8 "Enable/disable MSVC /utf-8 flag (recommended for fmt)" ON)
|
|
if (WIN32)
|
|
option(SPDLOG_WCHAR_CONSOLE "Decode UTF-8 and write with WriteConsoleW (Unicode console output)" OFF)
|
|
else ()
|
|
set(SPDLOG_WCHAR_CONSOLE OFF CACHE BOOL "non supported option" FORCE)
|
|
endif ()
|
|
if (SPDLOG_TIDY)
|
|
set(CMAKE_CXX_CLANG_TIDY "clang-tidy")
|
|
set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
|
|
message(STATUS "Enabled clang-tidy")
|
|
endif ()
|
|
if (SPDLOG_BUILD_SHARED)
|
|
set(BUILD_SHARED_LIBS ON)
|
|
set(CMAKE_POSITION_INDEPENDENT_CODE ON)
|
|
endif ()
|
|
if (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
|
|
# place dlls and libs and executables in the same directory
|
|
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin/$<CONFIG>)
|
|
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin/$<CONFIG>)
|
|
set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin/$<CONFIG>)
|
|
set(CMAKE_PDB_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin/$<CONFIG>)
|
|
# make sure __cplusplus is defined
|
|
add_compile_options(/Zc:__cplusplus)
|
|
# enable parallel build for the solution
|
|
add_compile_options(/MP)
|
|
endif ()
|
|
message(STATUS "spdlog version: ${SPDLOG_VERSION}")
|
|
message(STATUS "spdlog build type: " ${CMAKE_BUILD_TYPE})
|
|
message(STATUS "spdlog build shared: " ${BUILD_SHARED_LIBS})
|
|
message(STATUS "spdlog fmt external: " ${SPDLOG_FMT_EXTERNAL})
|
|
# ---------------------------------------------------------------------------------------
|
|
# Find {fmt} library
|
|
# ---------------------------------------------------------------------------------------
|
|
if (SPDLOG_FMT_EXTERNAL)
|
|
find_package(fmt REQUIRED CONFIG)
|
|
message(STATUS "Using external fmt lib version: ${fmt_VERSION}")
|
|
else ()
|
|
include(cmake/fmtlib.cmake)
|
|
endif ()
|
|
# ---------------------------------------------------------------------------------------
|
|
# Threads library is required
|
|
# ---------------------------------------------------------------------------------------
|
|
find_package(Threads REQUIRED)
|
|
# ---------------------------------------------------------------------------------------
|
|
# Library sources
|
|
# ---------------------------------------------------------------------------------------
|
|
set(SPDLOG_HEADERS
|
|
"include/spdlog/common.h"
|
|
"include/spdlog/file_event_handlers.h"
|
|
"include/spdlog/filename_t.h"
|
|
"include/spdlog/formatter.h"
|
|
"include/spdlog/fwd.h"
|
|
"include/spdlog/logger.h"
|
|
"include/spdlog/pattern_formatter.h"
|
|
"include/spdlog/source_loc.h"
|
|
"include/spdlog/spdlog.h"
|
|
"include/spdlog/stopwatch.h"
|
|
"include/spdlog/version.h"
|
|
"include/spdlog/details/circular_q.h"
|
|
"include/spdlog/details/file_helper.h"
|
|
"include/spdlog/details/fmt_helper.h"
|
|
"include/spdlog/details/log_msg.h"
|
|
"include/spdlog/details/async_log_msg.h"
|
|
"include/spdlog/details/mpmc_blocking_q.h"
|
|
"include/spdlog/details/null_mutex.h"
|
|
"include/spdlog/details/os.h"
|
|
"include/spdlog/details/err_helper.h"
|
|
"include/spdlog/bin_to_hex.h"
|
|
"include/spdlog/sinks/android_sink.h"
|
|
"include/spdlog/sinks/base_sink.h"
|
|
"include/spdlog/sinks/basic_file_sink.h"
|
|
"include/spdlog/sinks/callback_sink.h"
|
|
"include/spdlog/sinks/daily_file_sink.h"
|
|
"include/spdlog/sinks/dist_sink.h"
|
|
"include/spdlog/sinks/dup_filter_sink.h"
|
|
"include/spdlog/sinks/hourly_file_sink.h"
|
|
"include/spdlog/sinks/kafka_sink.h"
|
|
"include/spdlog/sinks/mongo_sink.h"
|
|
"include/spdlog/sinks/msvc_sink.h"
|
|
"include/spdlog/sinks/null_sink.h"
|
|
"include/spdlog/sinks/ostream_sink.h"
|
|
"include/spdlog/sinks/qt_sinks.h"
|
|
"include/spdlog/sinks/ringbuffer_sink.h"
|
|
"include/spdlog/sinks/rotating_file_sink.h"
|
|
"include/spdlog/sinks/sink.h"
|
|
"include/spdlog/sinks/stdout_color_sinks.h"
|
|
"include/spdlog/sinks/stdout_sinks.h"
|
|
"include/spdlog/sinks/syslog_sink.h"
|
|
"include/spdlog/sinks/systemd_sink.h"
|
|
"include/spdlog/sinks/tcp_sink.h"
|
|
"include/spdlog/sinks/udp_sink.h"
|
|
"include/spdlog/sinks/async_sink.h")
|
|
set(SPDLOG_SRCS
|
|
"src/common.cpp"
|
|
"src/logger.cpp"
|
|
"src/pattern_formatter.cpp"
|
|
"src/spdlog.cpp"
|
|
"src/details/file_helper.cpp"
|
|
"src/details/os_filesystem.cpp"
|
|
"src/details/log_msg.cpp"
|
|
"src/details/async_log_msg.cpp"
|
|
"src/details/err_helper.cpp"
|
|
"src/sinks/base_sink.cpp"
|
|
"src/sinks/basic_file_sink.cpp"
|
|
"src/sinks/rotating_file_sink.cpp"
|
|
"src/sinks/stdout_sinks.cpp"
|
|
"src/sinks/async_sink.cpp")
|
|
if (WIN32)
|
|
list(APPEND SPDLOG_SRCS
|
|
"src/details/os_windows.cpp"
|
|
"src/sinks/wincolor_sink.cpp")
|
|
list(APPEND SPDLOG_HEADERS
|
|
"include/spdlog/sinks/wincolor_sink.h"
|
|
"include/spdlog/details/tcp_client_windows.h"
|
|
"include/spdlog/details/udp_client_windows.h"
|
|
"include/spdlog/details/windows_include.h"
|
|
"include/spdlog/sinks/win_eventlog_sink.h")
|
|
else ()
|
|
list(APPEND SPDLOG_SRCS
|
|
"src/details/os_unix.cpp"
|
|
"src/sinks/ansicolor_sink.cpp")
|
|
list(APPEND SPDLOG_HEADERS
|
|
"include/spdlog/details/tcp_client_unix.h"
|
|
"include/spdlog/details/udp_client_unix.h"
|
|
"include/spdlog/sinks/ansicolor_sink.h")
|
|
endif ()
|
|
# ---------------------------------------------------------------------------------------
|
|
# Check if fwrite_unlocked/_fwrite_nolock is available
|
|
# ---------------------------------------------------------------------------------------
|
|
include(CheckSymbolExists)
|
|
if (WIN32)
|
|
check_symbol_exists(_fwrite_nolock "stdio.h" HAVE_FWRITE_UNLOCKED)
|
|
else ()
|
|
check_symbol_exists(fwrite_unlocked "stdio.h" HAVE_FWRITE_UNLOCKED)
|
|
endif ()
|
|
if (HAVE_FWRITE_UNLOCKED)
|
|
set(SPDLOG_FWRITE_UNLOCKED 1)
|
|
endif ()
|
|
# ---------------------------------------------------------------------------------------
|
|
# spdlog library
|
|
# ---------------------------------------------------------------------------------------
|
|
if (BUILD_SHARED_LIBS)
|
|
if (WIN32)
|
|
set(VERSION_RC ${CMAKE_CURRENT_BINARY_DIR}/version.rc)
|
|
configure_file(${CMAKE_CURRENT_SOURCE_DIR}/cmake/version.rc.in ${CMAKE_CURRENT_BINARY_DIR}/version.rc @ONLY)
|
|
endif ()
|
|
add_library(spdlog SHARED ${VERSION_RC})
|
|
target_compile_definitions(spdlog PUBLIC SPDLOG_SHARED_LIB)
|
|
if (MSVC)
|
|
# disable dlls related warnings on msvc
|
|
target_compile_options(spdlog PUBLIC $<$<AND:$<CXX_COMPILER_ID:MSVC>,$<NOT:$<COMPILE_LANGUAGE:CUDA>>>:/wd4251 /wd4275>)
|
|
endif ()
|
|
else ()
|
|
add_library(spdlog STATIC)
|
|
endif ()
|
|
set_target_properties(spdlog PROPERTIES CXX_VISIBILITY_PRESET hidden VISIBILITY_INLINES_HIDDEN ON)
|
|
add_library(spdlog::spdlog ALIAS spdlog)
|
|
target_sources(spdlog PRIVATE ${SPDLOG_SRCS})
|
|
target_sources(
|
|
spdlog
|
|
PUBLIC FILE_SET pub_headers
|
|
TYPE HEADERS
|
|
BASE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/include
|
|
FILES ${SPDLOG_HEADERS})
|
|
set(SPDLOG_INCLUDES_LEVEL "")
|
|
if (SPDLOG_SYSTEM_INCLUDES)
|
|
set(SPDLOG_INCLUDES_LEVEL "SYSTEM")
|
|
endif ()
|
|
target_include_directories(spdlog ${SPDLOG_INCLUDES_LEVEL} PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_LIST_DIR}/include>"
|
|
"$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>")
|
|
target_link_libraries(spdlog PUBLIC Threads::Threads)
|
|
target_link_libraries(spdlog PUBLIC fmt::fmt)
|
|
if (MSVC)
|
|
if (SPDLOG_MSVC_UTF8)
|
|
# Pass /utf-8 only for real MSVC (not clang-cl); see fmtlib and #3260.
|
|
target_compile_options(spdlog PUBLIC $<$<AND:$<COMPILE_LANGUAGE:CXX>,$<CXX_COMPILER_ID:MSVC>>:/utf-8>)
|
|
endif ()
|
|
endif ()
|
|
spdlog_enable_warnings(spdlog)
|
|
if (SPDLOG_SANITIZE_ADDRESS)
|
|
spdlog_enable_addr_sanitizer(spdlog)
|
|
elseif (SPDLOG_SANITIZE_THREAD)
|
|
spdlog_enable_thread_sanitizer(spdlog)
|
|
endif ()
|
|
set_target_properties(spdlog PROPERTIES VERSION ${SPDLOG_VERSION} SOVERSION
|
|
${SPDLOG_VERSION_MAJOR}.${SPDLOG_VERSION_MINOR})
|
|
set(SPDLOG_NAME spdlog-${SPDLOG_VERSION_MAJOR})
|
|
set_target_properties(spdlog PROPERTIES DEBUG_POSTFIX "${SPDLOG_DEBUG_POSTFIX}")
|
|
# ---------------------------------------------------------------------------------------
|
|
# Set prefix and source group for visual studio
|
|
# ---------------------------------------------------------------------------------------
|
|
if (CMAKE_GENERATOR MATCHES "Visual Studio")
|
|
source_group(TREE ${CMAKE_CURRENT_SOURCE_DIR}/include PREFIX include FILES ${SPDLOG_HEADERS})
|
|
source_group(TREE ${CMAKE_CURRENT_SOURCE_DIR}/src PREFIX sources FILES ${SPDLOG_SRCS})
|
|
source_group(sources FILES ${VERSION_RC})
|
|
endif ()
|
|
# ---------------------------------------------------------------------------------------
|
|
# Android support
|
|
# ---------------------------------------------------------------------------------------
|
|
if (ANDROID)
|
|
target_link_libraries(spdlog PUBLIC log)
|
|
endif ()
|
|
# ---------------------------------------------------------------------------------------
|
|
# Private defines according to the options
|
|
# ---------------------------------------------------------------------------------------
|
|
set(SPDLOG_UTF8_TO_WCHAR_CONSOLE ${SPDLOG_WCHAR_CONSOLE})
|
|
foreach (SPDLOG_OPTION
|
|
SPDLOG_CLOCK_COARSE
|
|
SPDLOG_PREVENT_CHILD_FD
|
|
SPDLOG_NO_THREAD_ID
|
|
SPDLOG_DISABLE_GLOBAL_LOGGER
|
|
SPDLOG_NO_TLS
|
|
SPDLOG_FWRITE_UNLOCKED
|
|
SPDLOG_UTF8_TO_WCHAR_CONSOLE)
|
|
if (${SPDLOG_OPTION})
|
|
target_compile_definitions(spdlog PRIVATE ${SPDLOG_OPTION})
|
|
endif ()
|
|
endforeach ()
|
|
if (SPDLOG_NO_TZ_OFFSET)
|
|
target_compile_definitions(spdlog PUBLIC SPDLOG_NO_TZ_OFFSET)
|
|
endif ()
|
|
# ---------------------------------------------------------------------------------------
|
|
# Build binaries
|
|
# ---------------------------------------------------------------------------------------
|
|
# examples
|
|
if (SPDLOG_BUILD_EXAMPLE OR SPDLOG_BUILD_ALL)
|
|
message(STATUS "Generating example(s)")
|
|
add_subdirectory(example)
|
|
spdlog_enable_warnings(example)
|
|
endif ()
|
|
# tests
|
|
if (SPDLOG_BUILD_TESTS OR SPDLOG_BUILD_ALL)
|
|
message(STATUS "Generating tests")
|
|
enable_testing()
|
|
add_subdirectory(tests)
|
|
endif ()
|
|
# benchmarks
|
|
if (SPDLOG_BUILD_BENCH OR SPDLOG_BUILD_ALL)
|
|
message(STATUS "Generating benchmarks")
|
|
add_subdirectory(bench)
|
|
endif ()
|
|
# ---------------------------------------------------------------------------------------
|
|
# Install
|
|
# ---------------------------------------------------------------------------------------
|
|
if (SPDLOG_INSTALL)
|
|
message(STATUS "Generating install")
|
|
install(
|
|
TARGETS spdlog
|
|
EXPORT spdlogTargets
|
|
LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}/${SPDLOG_NAME}"
|
|
ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}/${SPDLOG_NAME}"
|
|
RUNTIME DESTINATION "${CMAKE_INSTALL_BINDIR}/${SPDLOG_NAME}"
|
|
FILE_SET pub_headers
|
|
DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/${SPDLOG_NAME}")
|
|
message(STATUS "Installing spdlog in ${CMAKE_INSTALL_LIBDIR}/${SPDLOG_NAME}")
|
|
# Install CMake spdlogConfig.cmake, spdlogConfigVersion.cmake and spdlogTargets.cmake
|
|
set(project_config_in "${CMAKE_CURRENT_LIST_DIR}/cmake/spdlogConfig.cmake.in")
|
|
set(project_config_out "${CMAKE_CURRENT_BINARY_DIR}/spdlogConfig.cmake")
|
|
set(config_targets_file "spdlogConfigTargets.cmake")
|
|
set(version_config_file "${CMAKE_CURRENT_BINARY_DIR}/spdlogConfigVersion.cmake")
|
|
set(export_dest_dir "${CMAKE_INSTALL_LIBDIR}/cmake/${SPDLOG_NAME}")
|
|
install(EXPORT spdlogTargets DESTINATION ${export_dest_dir} NAMESPACE spdlog:: FILE ${config_targets_file})
|
|
include(CMakePackageConfigHelpers)
|
|
configure_package_config_file("${project_config_in}" "${project_config_out}" INSTALL_DESTINATION ${export_dest_dir})
|
|
write_basic_package_version_file("${version_config_file}" COMPATIBILITY SameMajorVersion)
|
|
install(FILES "${project_config_out}" "${version_config_file}" DESTINATION "${export_dest_dir}")
|
|
# CPack
|
|
include(cmake/spdlogCPack.cmake)
|
|
endif ()
|